[EasyLinux-Ubuntu] [OT] Ubuntu 10.04 will bei Laptop externen Monitor nicht

Stefan Luetje stefan.luetje at t-online.de
Do Jul 11 10:53:33 CEST 2013


Am 11. Jul 2013 um 10:36 CEST schrieb Uwe Herrmuth:
> Stefan Luetje schrieb am 11.07.2013 um 10:29:

> >,----
> >|     Host                            Date received (local)   Lag       Total lag
> >|  1. Date:                            2013-07-10  12:44:27   00:00:00   00:00:00
> >|  2. debian64.potato.lan              2013-07-10  12:44:27   00:00:00   00:00:00
> >|  3. fwd16.t-online.de                2013-07-10  12:44:28   00:00:01   00:00:01
> >|  4. mailout11.t-online.de            2013-07-10  12:44:31   00:00:03   00:00:04
> >|  5. ironport.ntm-gmbh.de             2013-07-11  10:12:18   21:27:47   21:27:51
> >|  6. mail.linux-new-media.de          2013-07-11  10:12:17  -00:00:01   21:27:50
> >|  7. ironport.ntm-gmbh.de             2013-07-11  10:12:19   00:00:02   21:27:52
> >|  8. w4z.linuxnewmedia.local          2013-07-11  10:10:03  -00:02:16   21:25:36
> >|  9. w4z.linuxnewmedia.local          2013-07-11  10:10:04   00:00:01   21:25:37
> >| 10. mailin52.aul.t-online.de         2013-07-11  10:12:20   00:02:16   21:27:53
> >| 11. ehead302.aul.t-online.de         2013-07-11  10:12:37   00:00:17   21:28:10
> >| 12. debian64.potato.lan              2013-07-11  10:20:20   00:07:43   21:35:53
> >| 13. debian64.potato.lan              2013-07-11  10:20:20   00:00:00   21:35:53
> >`----
> >
> >Eine Verzögerung von über 21 Std. bei ironport.ntm-gmbh.de :-(
> 
> Ah - das erklärt einiges.

Vielleicht hatte der Name, den ich in meiner Signatur erwähnte, dazu
geführt, dass meine Mail in einem Raster hängen blieb und noch einer
extra Behandlung bedurfte.

> BTW: Wie kommst DU an diese Übersicht? 

Das Skript dazu ist im Anhang.
Für den Aufruf steht in meiner ~/.muttrc folgendes:

macro index,pager "\eh"    "<pipe-message>~/bin/mailhops<enter>"    # View the path of the mail.


Gruß
Stefan
  
-- 
,-----------------------------------------------------------------------------.
|              Stefan Lütje             |            Jabber-ID:            |
|       stefan.luetje at t-online.de       |       Skelli at jabber.ccc.de       |
`----Key fingerprint = BCB2 48E4 9211 C975 5A3F  B192 9B6E CCCF 99CC 44FA-----'

-------------- nächster Teil --------------
#!/usr/bin/perl -w
# Copyright (c) 1999 Marius Gedminas <mgedmin at takas.lt>
# Shows the route of an Internet mail message
# Version 0.0.1pre-alpha
#
# Patched by Roland Rosenfeld <roland at spinnaker.de>
# $ Id: mailhops,v 1.3 2000/01/25 20:18:24 roland Exp roland $

use strict;
use POSIX qw(mktime);
use Date::Parse;

my $verbose = 0;

# Setup
my %Months = (
    Jan => 1,
    Feb => 2,
    Mar => 3,
    Apr => 4,
    May => 5,
    Jun => 6,
    Jul => 7,
    Aug => 8,
    Sep => 9,
    Oct => 10,
    Nov => 11,
    Dec => 12,
    );

# Read headers
$/ = '';
my $head = <>;
$head =~ s/\n\s+/ /g;
my @headers = split("\n", $head);

# Parse headers
my @hops;
for (@headers) {
  next unless /^(>?Received|Date):/;
  my $time;
  my $host;
  my $from;
  if (/^Date:\s+(.*)/) {
    $host = "Date:";
    $time = $1;
    $from = "";
  } else {
    $host = "(unknown)";
    $host = $1 if /\sby\s+([a-z0-9\-_+.]+)\s/ && $1 ne "uid";
    $from = "(unknown)";
    $from = $1 if /\sfrom\s+([a-z0-9\-_+.]+(?:\s+[(].+?[)]))\s/;
    $time = "(unknown)";
    $time = $1 if /;\s+(.+)$/;
    $time =~ s/using.*//;
  }

  my $epoch = str2time ($time);

  unshift @hops, { HOST => $host, FROM => $from, TIME => $epoch};
}

# Print output
print "    Host                            Date received (local)   Lag       Total lag\n";
my $nr = 0;
my ($first, $prev);
for (@hops) {
  my $host = $_->{HOST};
  my $from = $_->{FROM};
  my $time = $_->{TIME};
  $first = $prev = $time unless defined $first;
  printf "%2d. %-31.31s", ++$nr, $host;
  do { print "\n"; next } unless defined $time;

  my $delta = $time - $prev;
  my $neg = $delta < 0; $delta = abs($delta);
  my $delta_h = int($delta / 3600);
  my $delta_m = int(($delta - $delta_h * 3600) / 60);
  my $delta_s = ($delta - $delta_h * 3600 - $delta_m * 60);

  my ($sec,$min,$hour,$day,$mon,$year,undef,undef,$dst) = localtime($time);

  printf "  %4d-%02d-%02d  %02d:%02d:%02d  %s%02d:%02d:%02d",
         1900+$year, $mon+1, $day, $hour, $min, $sec,
	 $neg ? '-' : ' ', $delta_h, $delta_m, $delta_s;

  $delta = $time - $first;
  $neg = $delta < 0; $delta = abs($delta);
  $delta_h = int($delta / 3600);
  $delta_m = int(($delta - $delta_h * 3600) / 60);
  $delta_s = ($delta - $delta_h * 3600 - $delta_m * 60);
  printf "  %s%02d:%02d:%02d\n",
	 $neg ? '-' : ' ', $delta_h, $delta_m, $delta_s;
  print  "     from $from\n" if $verbose;
  $prev = $time;
}
-------------- nächster Teil --------------
Ein Dateianhang mit Binärdaten wurde abgetrennt...
Dateiname   : nicht verfügbar
Dateityp    : application/pgp-signature
Dateigröße  : 198 bytes
Beschreibung: Digital signature
URL         : <http://www.easylinux.de/pipermail/ubuntu/attachments/20130711/f9724937/attachment-0001.pgp>


Mehr Informationen über die Mailingliste Ubuntu